# Maintainer: KITAGAWA Masahiro <arctica0316@gmail.com>
pkgname=lightzone
pkgver=5.0.0.beta1
pkgrel=0
pkgdesc="Open-source professional-level digital darkroom software"
url="https://github.com/ktgw0316/LightZone/"
license=('custom:BSD-3-Clause')
arch=('x86_64')

depends=('java-runtime>15'
 'javahelp2'
 'lcms2'
 'lensfun'
 'libjpeg-turbo'
 'libtiff'
 'libxml2')
makedepends=('java-environment>15'
 'ant'
 'gcc'
 'make'
 'git'
 'libx11'
 'pkgconf'
 'rsync'
 'javahelp2'
 'lcms2'
 'libjpeg-turbo'
 'libtiff')

vcsname='LightZone'
source=("git+https://github.com/ktgw0316/${vcsname}.git")
md5sums=('SKIP')

build() {
  # Set $JAVA_HOME and $ANT_HOME
  if [ -d /usr/lib/jvm/java-17-openjdk ]; then
    export JAVA_HOME=/usr/lib/jvm/java-17-openjdk
  else
    export JAVA_HOME=/usr/lib/jvm/default
  fi

  # Parallel compilation fails, so disable it
  export MAKEFLAGS="-j1"

  cd "${srcdir}/${vcsname}/"
  ant -f linux/build.xml jar
}

package() {
  cd "${srcdir}/${vcsname}/"

  _libexecdir=/usr/lib
  install -dm 0755 "${pkgdir}/${_libexecdir}/${pkgname}"
  cp -pH linux/products/*.so "${pkgdir}/${_libexecdir}/${pkgname}"
  _javadir=/usr/share/java
  install -dm 0755 "${pkgdir}/${_javadir}/${pkgname}"
  cp -pH lightcrafts/products/dcraw_lz "${pkgdir}/${_javadir}/${pkgname}"
  cp -pH lightcrafts/products/LightZone-forkd "${pkgdir}/${_javadir}/${pkgname}"
  cp -pH linux/products/*.jar "${pkgdir}/${_javadir}/${pkgname}"

# create icons and shortcuts
  _datadir=/usr/share
  install -dm 0755 "${pkgdir}/${_datadir}/applications"
  install -m 644 linux/products/lightzone.desktop "${pkgdir}/${_datadir}/applications/"
  cp -pHR linux/icons "${pkgdir}/${_datadir}/"

  _bindir=/usr/bin
  install -dm 0755 "${pkgdir}/${_bindir}"
  install -m 755 "linux/products/${pkgname}" "${pkgdir}/${_bindir}"
}
