
FIND_PACKAGE(CyrusSASL REQUIRED)

ADD_LIBRARY(${LIBNAME}-sasl src/SimpleLoginManager.cpp)

TARGET_LINK_LIBRARIES(${LIBNAME}-sasl PUBLIC ${LIBNAME} PRIVATE sasl2)
SET_TARGET_PROPERTIES ( ${LIBNAME}-sasl PROPERTIES
    SOVERSION "${SOVERSION}"
    CLEAN_DIRECT_OUTPUT 1
    VERSION "${PROJECT_VERSION}"
    POSITION_INDEPENDENT_CODE ${BUILD_POSITION_INDEPENDENT}
    PUBLIC_HEADER "include/pdcom5/SimpleLoginManager.h"
    CXX_STANDARD_REQUIRED 1
    CXX_STANDARD 11
)

IF (BUILD_SHARED_LIBS)
    SET_TARGET_PROPERTIES ( ${LIBNAME}-sasl PROPERTIES
        CXX_VISIBILITY_PRESET "hidden"
        VISIBILITY_INLINES_HIDDEN 1
    )
ENDIF()

TARGET_INCLUDE_DIRECTORIES(${LIBNAME}-sasl PUBLIC
    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
    "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
    "$<INSTALL_INTERFACE:include>"
)

GENERATE_EXPORT_HEADER(${LIBNAME}-sasl)

INSTALL (TARGETS ${LIBNAME}-sasl
    EXPORT ${LIBNAME}-saslTargets
    ARCHIVE DESTINATION  "${CMAKE_INSTALL_LIBDIR}"
    LIBRARY DESTINATION  "${CMAKE_INSTALL_LIBDIR}"
    RUNTIME DESTINATION  "${CMAKE_INSTALL_BINDIR}"
    PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBNAME}"
    COMPONENT sasl
)

INSTALL (FILES "${CMAKE_CURRENT_BINARY_DIR}/${LIBNAME}-sasl_export.h"
    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBNAME}")


INSTALL(EXPORT ${LIBNAME}-saslTargets
    NAMESPACE EtherLab::
    FILE ${LIBNAME}-saslTargets.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${LIBNAME}
)

EXPORT(EXPORT ${LIBNAME}-saslTargets
    FILE "${CMAKE_CURRENT_BINARY_DIR}/../src/${LIBNAME}/${LIBNAME}-saslTargets.cmake"
    NAMESPACE EtherLab::
)
