
FIND_PACKAGE(CyrusSASL REQUIRED)

ADD_LIBRARY(${LIBNAME}-sasl SHARED src/SimpleLoginManager.cpp)
TARGET_LINK_LIBRARIES(${LIBNAME}-sasl PUBLIC ${LIBNAME} PRIVATE ${CYRUS_SASL_SHARED_LIB})
SET_TARGET_PROPERTIES ( ${LIBNAME}-sasl PROPERTIES
    SOVERSION "${SOVERSION}"
    CLEAN_DIRECT_OUTPUT 1
    CXX_VISIBILITY_PRESET "hidden"
    VISIBILITY_INLINES_HIDDEN 1
    VERSION "${PROJECT_VERSION}"
    PUBLIC_HEADER "include/pdcom5/SimpleLoginManager.h"
    CXX_STANDARD_REQUIRED 1
    CXX_STANDARD 11
)
TARGET_INCLUDE_DIRECTORIES(${LIBNAME}-sasl PUBLIC
    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
    "$<INSTALL_INTERFACE:include>"
)
TARGET_INCLUDE_DIRECTORIES(${LIBNAME}-sasl PRIVATE
    ${CYRUS_SASL_INCLUDE_DIR}
)

INSTALL (TARGETS ${LIBNAME}-sasl
    EXPORT ${LIBNAME}-saslTargets
    ARCHIVE DESTINATION  "${CMAKE_INSTALL_LIBDIR}"
    LIBRARY DESTINATION  "${CMAKE_INSTALL_LIBDIR}"
    RUNTIME DESTINATION  "${CMAKE_INSTALL_BINDIR}"
    PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBNAME}"
    COMPONENT sasl
)


INSTALL(EXPORT ${LIBNAME}-saslTargets
    NAMESPACE EtherLab::
    FILE ${LIBNAME}-saslTargets.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${LIBNAME}
)

EXPORT(EXPORT ${LIBNAME}-saslTargets
    FILE "${CMAKE_CURRENT_BINARY_DIR}/${LIBNAME}/${LIBNAME}-saslTargets.cmake"
    NAMESPACE EtherLab::
)
